Обслуживание абонентских линий

Обслуживание абонентских линий – 3 Главная страница --- Home page

«Я тут наваял за недельку шикарный скрипт.

В нём анализируется портянка SUSCP:SNB=snb,LIST;

ЗЫ: Скрипт написан на WinFiol 7-ой версии и под EM141 для аналоговых абонентов.

В дальнейшем наваяю и для "цифры".

ЗЫЗЫ: Указал все необходимые коментарии для понятия действия скрипта.

Прошу прощения за мой английский».

ЮЗАЙТЕ, ДРУГИ !!!

Редакция 2007-12-04 16:00 (мск)

@@ GENERAL AVAILABILITY FOR SUPPLEMENTARY SERVICES SUBSCRIBER CATEGORIES

@@ Analysing of printout:

@@ ALARM CALL SERVICE

@@ ABBREVIATED DIALLING SERVICE

@@ CALL WAITING SERVICE

@@ FIXED DESTINATION CALL DATA

@@ OUTGOING CALL BARRING SUBSCRIBER CONTROLLED DATA

@@ DO NOT DISTURB SERVICE

@@ CALL FORWARDING BUSY VARIABLE NUMBER SERVICE

@@ CALL FORWARDING NO REPLY VARIABLE NUMBER SERVICE

@@ CALL FORWARDING UNCONDITIONAL VARIABLE NUMBER SERVICE

@@ Printout without analysing:

@@ THREE-PARTY SERVICE

@@ LAST NUMBER REPETITION DATA

@@ CALLING LINE IDENTIFICATION PRESENTATION SERVICE DATA

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@@@ @@ @@ @@ @@ @@@

@@@ @@@ @@@@@ @@@@@ @@ @@ @@@@ @@@@@ @@@@@@@

@@@ @@@@@@@@@@@ @@@@ @@@ @@ @@@@ @@@@@ @@@@@@@

@@@@ @@@@@@ @@@ @@@@ @@ @@@@@@ @@@@@@@

@@@@@@@@@ @@@@@ @@@ @@ @@ @@@@@@@ @@@@@@@

@@@ @@@ @@@@@ @@@ @@@@ @@ @@@ @@@@@@ @@@@@@@

@@@@ @@@@@@ @@@ @@@@ @@ @@@@ @@@@@ @@@@@@@

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@R-

@clear

@@--------------------------@@

@@ DEFINE DATE and TIME @@

@@--------------------------@@

@getdate {date} YYYYMMDD

@gettime {time} HHMMSS

@@---------------------@@

@@ DEFINE FILEPATH @@

@@---------------------@@

@set {FilePath} = "D:\SUSCPall"

@@-----------------------------@@

@@ Internal Numbering Plan @@

@@-----------------------------@@

@set {IntNumPlanFirst} = 200000

@set {IntNumPlanLast} = 579999

@if {IntNumPlanFirst} > 9999 then set {LenghtNumber} = 5

@if {IntNumPlanFirst} > 99999 then set {LenghtNumber} = 6

@if {IntNumPlanFirst} > 999999 then set {LenghtNumber} = 7

@if {IntNumPlanFirst} > 9999 then set {LenghtAreaCode} = 5

@if {IntNumPlanFirst} > 99999 then set {LenghtAreaCode} = 4

@if {IntNumPlanFirst} > 999999 then set {LenghtAreaCode} = 3

@set {NextPosArea} = {LenghtAreaCode} + 1

@@-----------------------------------------@@

@@ ENTER NUMBER @@

@@ (and analysing internal numbering plan) @@

@@-----------------------------------------@@

@label ASKnumber

@ask {snbloop} "Enter first number"

@if {snbloop} <= {IntNumPlanFirst} then goto ASKnumber

@if {snbloop} => {IntNumPlanLast} then goto ASKnumber

@ask {snbloopend} "Enter last number"

@if {snbloopend} = "" then goto SingleNumber

@if {snbloop} > {snbloopend} then goto ASKnumber

@if {snbloopend} <= {IntNumPlanFirst} then goto ASKnumber

@if {snbloopend} => {IntNumPlanLast} then goto ASKnumber

@@----------------------@@

@@ DEFINE FILENAMES @@

@@----------------------@@

@set {DateTimeSNBs} = {date}+"-"+{time}+"--"+{snbloop}+"-"+{snbloopend}

@SET {filename} = {FilePath}+"\SUSCClist-"+{DateTimeSNBs}+".txt"

@SET {filenameFroUnreasonableValue} = {FilePath}+"\UnreasonableValue-"+{DateTimeSNBs}+".txt"

@SET {filenameFroRC} = {FilePath}+"\RC-" +{DateTimeSNBs}+".txt"

@SET {filenameFroPBX} = {FilePath}+"\PBX-" +{DateTimeSNBs}+".txt"

@SET {filenameForISDNE} = {FilePath}+"\ISDNE-" +{DateTimeSNBs}+".txt"

@SET {filenameFroPBXpxr} = {FilePath}+"\PBXpxr-" +{DateTimeSNBs}+".txt"

@SET {filenameDefaultSCL} = {FilePath}+"\DefaultSCL-" +{DateTimeSNBs}+".txt"

@SET {filenameFroVacantNumber} = {FilePath}+"\VacantNumber-" +{DateTimeSNBs}+".txt"

@if {snbloop} = {snbloopend} then goto SingleNumber

@goto global_loop

@@--------------------------------------@@

@@ DEFINE FILENAMES for single number @@

@@--------------------------------------@@

@label SingleNumber

@set {snbloopend} = 0

@set {DateTimeSNB} = {date}+"-"+{time}+"--"+{snbloop}

@SET {filename} = {FilePath}+"\SUSCClist-"+{DateTimeSNB}+".txt"

@SET {filenameFroUnreasonableValue} = {FilePath}+"\UnreasonableValue-"+{DateTimeSNB}+".txt"

@SET {filenameFroRC} = {FilePath}+"\RC-" +{DateTimeSNB}+".txt"

@SET {filenameFroPBX} = {FilePath}+"\PBX-" +{DateTimeSNB}+".txt"

@SET {filenameForISDNE} = {FilePath}+"\ISDNE-" +{DateTimeSNB}+".txt"

@SET {filenameFroPBXpxr} = {FilePath}+"\PBXpxr-" +{DateTimeSNB}+".txt"

@SET {filenameDefaultSCL} = {FilePath}+"\DefaultSCL-" +{DateTimeSNB}+".txt"

@SET {filenameFroVacantNumber} = {FilePath}+"\VacantNumber-" +{DateTimeSNB}+".txt"

@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@ @@

@@ START global loop @@

@@ @@

@@@@@@@@@@@@@@@@@@@@@@@@@@@

@label global_loop

@gosub commdatazero

@@------------------------@@

@@ COMMAND STSUP BASIC @@

@@------------------------@@

STSUP:SNB={snbloop};

@COPY {_line1} {NotAccepted} 1 12

@if {NotAccepted} = "NOT ACCEPTED" then goto NotAccepted

@copy {_line4} {adm} 1 2

@if {adm} = "NC" then goto NotConnected

@@ --- COMMAND STSUP define PBX-number ---

@copy {_line5} {pxrPBX} 1 3

@if {pxrPBX} <> "PXR" then goto commandSUKWP

@copy {_line6} {pxrPBX} 1 5

@set {posPNB} = 13 + {LenghtAreaCode}

@copy {_line6} {PNB} {posPNB} {LenghtNumber}

@copy {_line6} {pxrPBX} 1 5

@comment SNB={snbloop} define default SCL.

@APPEND {filenameFroPBXpxr} "PBXnumber="+{PNB}+",PXR="+{pxrPBX}+",SNB="+{snbloop}

@@-------------------@@

@@ COMMAND SUKWP @@

@@-------------------@@

@label commandSUKWP

SUKWP:SNB={snbloop};

@COPY {_line4} {kword} 33 4

@if {kword} = "" then goto SUSCPLIST

@set {command} = "SUKWI:SNB="

@set {data}=",KWORD="+{kword}

@gosub AppendCommandToFile

@@--------------------------------@@

@@ START ANALYSING SUSCP LIST @@

@@--------------------------------@@

@label SUSCPLIST

SUSCP:SNB={snbloop},LIST;

@copy {_lines[3]} {snb} {NextPosArea} {LenghtNumber}

@COPY {_lines[3]} {sut} 35 2

@if {sut} = "NC" then goto NUMBER_NC

@COPY {_lines[3]} {cos} 67 5

@if {cos} = "ISDNE" then goto SNBisISDNE

@COPY {_lines[3]} {scl[1]} 39 8

@if {scl[1]} = "" then goto DefaultSCL

@find {blockidx} {_lines} "GENERAL AVAILABILITY FOR SUPPLEMENTARY SERVICES SUBSCRIBER CATEGORIES"

@foreach {blockidx} set {lineGEN} = {_currline}

@find {blockidx} {_lines} "ALARM CALL SERVICE"

@foreach {blockidx} set {lineALS} = {_currline}

@find {blockidx} {_lines} "ABBREVIATED DIALLING SERVICE"

@foreach {blockidx} set {lineADI} = {_currline}

@find {blockidx} {_lines} "CALL WAITING SERVICE"

@foreach {blockidx} set {lineCAW} = {_currline}

@find {blockidx} {_lines} "THREE-PARTY SERVICE"

@foreach {blockidx} set {lineENQ} = {_currline}

@find {blockidx} {_lines} "FIXED DESTINATION CALL DATA"

@foreach {blockidx} set {lineFDC} = {_currline}

@find {blockidx} {_lines} "LAST NUMBER REPETITION DATA"

@foreach {blockidx} set {lineLNR} = {_currline}

@find {blockidx} {_lines} "OUTGOING CALL BARRING SUBSCRIBER CONTROLLED DATA"

@foreach {blockidx} set {lineCCB} = {_currline}

@find {blockidx} {_lines} "DO NOT DISTURB SERVICE"

@foreach {blockidx} set {lineDDB} = {_currline}

@find {blockidx} {_lines} "CALLING LINE IDENTIFICATION PRESENTATION SERVICE DATA"

@foreach {blockidx} set {lineCLIP} = {_currline}

@find {blockidx} {_lines} "CALL FORWARDING BUSY VARIABLE NUMBER SERVICE"

@foreach {blockidx} set {lineCFBV} = {_currline}

@find {blockidx} {_lines} "CALL FORWARDING NO REPLY VARIABLE NUMBER SERVICE"

@foreach {blockidx} set {lineCFNRV} = {_currline}

@find {blockidx} {_lines} "CALL FORWARDING UNCONDITIONAL VARIABLE NUMBER SERVICE"

@foreach {blockidx} set {lineCFUV} = {_currline}

@if {lineALS} = {lineGEN} then set {lineALSresult} = "no service"

@if {lineADI} = {lineALS} then set {lineADIresult} = "no service"

@if {lineCAW} = {lineADI} then set {lineCAWresult} = "no service"

@if {lineENQ} = {lineCAW} then set {lineENQresult} = "no service"

@if {lineFDC} = {lineENQ} then set {lineFDCresult} = "no service"

@if {lineLNR} = {lineFDC} then set {lineLNRresult} = "no service"

@if {lineCCB} = {lineLNR} then set {lineCCBresult} = "no service"

@if {lineDDB} = {lineCCB} then set {lineDDBresult} = "no service"

@if {lineCLIP} = {lineDDB} then set {lineCLIPresult} = "no service"

@if {lineCFBV} = {lineCLIP} then set {lineCFBVresult} = "no service"

@if {lineCFNRV} = {lineCFBV} then set {lineCFNRVresult} = "no service"

@if {lineCFUV} = {lineCFNRV} then set {lineCFUVresult} = "no service"

@if {lineALS} <> {lineGEN} then set {lineALSresult} = "yes service"

@if {lineADI} <> {lineALS} then set {lineADIresult} = "yes service"

@if {lineCAW} <> {lineADI} then set {lineCAWresult} = "yes service"

@if {lineENQ} <> {lineCAW} then set {lineENQresult} = "yes service"

@if {lineFDC} <> {lineENQ} then set {lineFDCresult} = "yes service"

@if {lineLNR} <> {lineFDC} then set {lineLNRresult} = "yes service"

@if {lineCCB} <> {lineLNR} then set {lineCCBresult} = "yes service"

@if {lineDDB} <> {lineCCB} then set {lineDDBresult} = "yes service"

@if {lineCLIP} <> {lineDDB} then set {lineCLIPresult} = "yes service"

@if {lineCFBV} <> {lineCLIP} then set {lineCFBVresult} = "yes service"

@if {lineCFNRV} <> {lineCFBV} then set {lineCFNRVresult} = "yes service"

@if {lineCFUV} <> {lineCFNRV} then set {lineCFUVresult} = "yes service"

@set {scline} = 4

@set {sc} = 2

@set {x}=1

@set {megascl} = {scl[1]}

@label sclread

@copy {_lines[{scline}]} {scl[{sc}]} 1 8

@if {scl[{sc}]} = "" then goto suscc_snb_scl

@set {megascl} = {megascl} + "&" + {scl[{sc}]}

@inc {scline}

@inc {sc}

@inc {x}

@if {x} > 100 then end

@goto SCLread

@@------------------------@@

@@ CREATE COMMAND SUSCC @@

@@------------------------@@

@label suscc_snb_scl

@comment SUSCC:SNB={snb},SCL={megascl};

@APPEND {filename} "SUSCC:SNB="+{snb}+",SCL="+{megascl}+";"

@@---------------------------------------------@@

@@ ANALYSING DIFINE SUBSCRIBER SERVICE CLASS @@

@@---------------------------------------------@@

@label sclALL

@if {lineALSresult} = "yes service" then GOSUB ALSdata

@if {lineADIresult} = "yes service" then GOSUB ADIdata

@if {lineCAWresult} = "yes service" then GOSUB CAWdata

@if {lineENQresult} = "yes service" then GOSUB ENQdata

@if {lineFDCresult} = "yes service" then GOSUB FDCdata

@if {lineCCBresult} = "yes service" then GOSUB CCBdata

@if {lineDDBresult} = "yes service" then GOSUB DDBdata

@if {lineCLIPresult} = "yes service" then GOSUB CLIPdata

@if {lineCFBVresult} = "yes service" then GOSUB CFBVdata

@if {lineCFNRVresult} = "yes service" then GOSUB CFNRVdata

@if {lineCFUVresult} = "yes service" then GOSUB CFUVdata

@@-----------------@@

@@ END global loop @@

@@-----------------@@

@label nextSNB

@inc {snbloop}

@if {snbloop} <= {snbloopend} then goto global_loop

@@--------------@@

@@ END PROGRAMM @@

@@--------------@@

@label end

@comment ---------------

@comment - alles kaput -

@comment ---------------

@end

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@-----------------@@

@@ Default SCL @@

@@-----------------@@

@label DefaultSCL

@comment On SNB={snbloop} define default SCL.

@APPEND {filenameDefaultSCL} {snbloop}

@goto nextSNB

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@ @@

@@ ANALYSING ERROR IN EXECUTE COMMAND STSUP @@

@@ @@

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@-------------------@@

@@ NOT CONNECTED @@

@@-------------------@@

@label NotConnected

@comment SNB={snbloop} no connected

@APPEND {filenameFroVacantNumber} {snbloop}

@goto nextSNB

@@------------------@@

@@ NOT ACCEPTED @@

@@------------------@@

@label NotAccepted

@COPY {_line2} {UnreasonableValue} 1 18

@if {UnreasonableValue} = "UNREASONABLE VALUE" then goto UnreasonableValue

@COPY {_line2} {FaultCode} 1 14

@if {FaultCode} = "FAULT CODE 17" then goto SNBisPBX

@if {FaultCode} = "FAULT CODE 22" then goto SNBonRC

@if {FaultCode} = "FAULT CODE 23" then goto SNBisISDNE

@label UnreasonableValue

@comment UNREASONABLE VALUE SNB={snbloop}

@APPEND {filenameFroUnreasonableValue} {snbloop}

@goto nextSNB

@label SNBisPBX

@comment SNB={snbloop} is PBX-number

@APPEND {filenameFroPBX} {snbloop}

@goto commandSUKWP

@label SNBonRC

@comment Need SUSCP:SNB={snbloop}; for find the RC

@APPEND {filenameFroRC} {snbloop}

@goto nextSNB

@label SNBisISDNE

@comment Need IUSCP:SNB={snbloop};

@APPEND {filenameForISDNE} {snbloop}

@goto nextSNB

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@@ @@@

@@@ CYCLED SUB-PROGRAMMS @@@

@@@ @@@

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@------------------------@@

@@ COMMAND + DATA to ZERO @@

@@------------------------@@

@label commdatazero

@set {command} = ""

@set {data} = ""

@return

@@-------------------------------@@

@@ INSERT COMMAND + DATA to file @@

@@-------------------------------@@

@label AppendCommandToFile

@comment {command}{snbloop}{data};

@APPEND {filename} {command}+{snbloop}+{data}+";"

@return

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@@ @@@

@@@ ANALYSING DIFINE SUBSCRIBER SERVICE CLASS DETAILED @@@

@@@ @@@

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@LABEL SUBSCRIBE_SERVICES_DETAILED

@@--------------------@@

@@ ALARM CALL SERVICE @@

@@--------------------@@

@label ALSdata

@if {lineALSresult} = "no service" then return

@gosub commdatazero

@set {command} = "SUACI:SNB="

@set {TimeStartLine} = {lineALS} + 4

@set {TimeNextLine} = {TimeStartLine}

@set {timeN} = 1

@label loopALS

@copy {_lines[{TimeNextLine}]} {time[{timeN}]} 1 4

@copy {_lines[{TimeNextLine}]} {nd[{timeN}]} 10 2

@copy {_lines[{TimeNextLine}]} {pn[{timeN}]} 20 2

@label pn

@if {pn[{timeN}]} = "" then goto nd

@set {data} = ",DIN="+{time[{timeN}]}+",PN="+{pn[{timeN}]}

@gosub AppendCommandToFile

@goto looptimeN

@label nd

@if {nd[{timeN}]} = "" then goto time

@set {data} = ",DIN="+{time[{timeN}]}+",ND="+{nd[{timeN}]}

@gosub AppendCommandToFile

@goto looptimeN

@label time

@if {time[{timeN}]} = "" then return

@set {data} = ",DIN="+{time[{timeN}]}

@gosub AppendCommandToFile

@goto looptimeN

@label looptimeN

@inc {timeN}

@if {timeN} = 10 then end

@inc {TimeNextLine}

@goto loopALS

@label return

@return

@@------------------------------@@

@@ ABBREVIATED DIALLING SERVICE @@

@@------------------------------@@

@label ADIdata

@set {x} = 1

@if {lineADIresult} = "no service" then return

@gosub commdatazero

@set {DinStartLine} = {lineADI} + 2

@set {DinNextLine} = {DinStartLine}

@set {DinN} = 1

@find {blockidx} {_lines} "ABBREVIATED DIALLING SERVICE"

@foreach {blockidx} set {lineADI} = {_currline}

@find {blockidx} {_lines} "STORE SIZE IS.*"

@foreach {blockidx} set {StoreSizeIs} = {_currline}

@copy {_lines[{StoreSizeIs}]} {StoreSize} 16 2

@if {StoreSize} = " 5" then goto loopADI

@set {command} = "SUALC:SNB="

@set {data} = ",ABLS=" + {StoreSize}

@gosub AppendCommandToFile

@label loopADI

@copy {_lines[{DinNextLine}]} {din[{DinN}]} 1 1

@copy {_lines[{DinNextLine}]} {SnbADI[{DinN}]} 3 20

@if {din[{DinN}]} = "" then return

@set {command} = "SUADC:SNB="

@set {data} = ",DIN="+{din[{DinN}]}+"#10"+{SnbADI[{DinN}]}

@gosub AppendCommandToFile

@inc {DinNextLine}

@goto loopADI

@return

@@----------------------@@

@@ CALL WAITING SERVICE @@

@@----------------------@@

@label CAWdata

@if {lineCAWresult} = "no service" then return

@gosub commdatazero

@set {CawActivLine} = {lineCAW} + 3

@copy {_lines[{CawActivLine}]} {Caw} 1 3

@if {Caw} = "NO " then return

@if {Caw} = "YES" then set {command} = "SUCWI:SNB="

@gosub AppendCommandToFile

@return

@@-----------------------------@@

@@ FIXED DESTINATION CALL DATA @@

@@-----------------------------@@

@label FDCdata

@if {lineFDCresult} = "no service" then return

@gosub commdatazero

@set {FdcActivLine} = {lineFDC} + 3

@set {FdcDinLine} = {lineFDC} + 6

@copy {_lines[{FdcActivLine}]} {ActivFDC} 1 3

@copy {_lines[{FdcDinLine}]} {DinFDC} 1 20

@copy {_lines[{FdcDinLine}]} {TdsFDC} 32 2

@if {ActivFDC} = "NO" then return

@set {command} = "SUHLI:SNB="

@set {data} = ",DIN="+{DinFDC}+",TDS="+{TdsFDC}

@gosub AppendCommandToFile

@return

@@--------------------------------------------------@@

@@ OUTGOING CALL BARRING SUBSCRIBER CONTROLLED DATA @@

@@--------------------------------------------------@@

@label CCBdata

@if {lineCCBresult} = "no service" then return

@gosub commdatazero

@set {CcbActivLine} = {lineCCB} + 3

@set {CcbActivBP} = {lineCCB} + 6

@set {CcbDefinBP[1]} = {lineCCB} + 9

@set {CcbDefinBP[2]} = {lineCCB} + 10

@copy {_lines[{CcbActivLine}]} {ActivCCB} 1 3

@copy {_lines[{CcbActivBP}]} {ActivBP} 1 2

@copy {_lines[{CcbDefinBP[1]}]} {DefinBP[1]} 1 2

@if {DefinBP[1]} = "" then return

@set {dataBP} = {DefinBP[1]}

@set {y} = 1

@set {x} = 2

@set {n} = 2

@set {PosDefinBP[{n}]} = {x} * 6 - 6

@label posBP

@copy {_lines[{CcbDefinBP[{y}]}]} {DefinBP[{n}]} {PosDefinBP[{n}]} 2

@if {DefinBP[{n}]} = "" then goto commandSUCBC

@set {dataBP} = {dataBP} + "&" + {DefinBP[{n}]}

@inc {x}

@inc {n}

@set {PosDefinBP[{n}]} = {x} * 6 - 6

@if {PosDefinBP[{n}]} > 54 then gosub Y2X1

@goto posBP

@label commandSUCBC

@set {command} = "SUCBC:SNB="

@set {data} = ",BP="+{dataBP}

@gosub AppendCommandToFile

@if {ActivCCB} = "YES" then gosub commandSUCBI

@return

@label commandSUCBI

@set {command} = "SUCBI:SNB="

@set {data} = ",BP="+{ActivBP}

@gosub AppendCommandToFile

@return

@label Y2X1

@set {y} = 2

@set {x} = 1

@set {PosDefinBP[11]}=1

@return

@@------------------------@@

@@ DO NOT DISTURB SERVICE @@

@@------------------------@@

@label DDBdata

@if {lineDDBresult} = "no service" then return

@gosub commdatazero

@set {DdbActivLine} = {lineDDB} + 2

@copy {_lines[{DdbActivLine}]} {ActivDDB} 1 3

@if {ActivDDB} = "NO" then return

@set {command} = "SUCDI:SNB="

@set {data} = ""

@gosub AppendCommandToFile

@return

@@----------------------------------------------@@

@@ CALL FORWARDING BUSY VARIABLE NUMBER SERVICE @@

@@----------------------------------------------@@

@label CFBVdata

@if {lineCFBVresult} = "no service" then return

@gosub commdatazero

@set {CfbvActivLine} = {lineCFBV} + 3

@set {CfbvDinLine} = {lineCFBV} + 12

@copy {_lines[{CfbvActivLine}]} {ActivCFBV} 10 3

@copy {_lines[{CfbvDinLine}]} {DinCFBV} 1 20

@if {DinCFBV} <> "" then gosub commandSUDNCcfbv

@if {ActivCFBV} = "YES" then gosub commandSFSAIcfbv

@return

@label commandSUDNCcfbv

@set {command} = "SUDNC:SNB="

@set {data} = ",SERVICE=CFBV,DIN="+{DinCFBV}

@gosub AppendCommandToFile

@gosub commdatazero

@return

@label commandSFSAIcfbv

@set {command} = "SFSAI:SNB="

@set {data} = ",SERVICE=CFBV"

@gosub AppendCommandToFile

@gosub commdatazero

@return

@@--------------------------------------------------@@

@@ CALL FORWARDING NO REPLY VARIABLE NUMBER SERVICE @@

@@--------------------------------------------------@@

@label CFNRVdata

@if {lineCFNRVresult} = "no service" then return

@gosub commdatazero

@set {CfnrvActivLine} = {lineCFNRV} + 3

@set {CfnrvRtimeLine} = {lineCFNRV} + 9

@set {CfnrvDinLine} = {lineCFNRV} + 15

@copy {_lines[{CfnrvActivLine}]} {ActivCFNRV} 10 3

@copy {_lines[{CfnrvRtimeLine}]} {RtimeCFNRV} 1 2

@copy {_lines[{CfnrvDinLine}]} {DinCFNRV} 1 20

@if {DinCFBV} <> "" then gosub commandSUDNCcfnrv

@if {ActivCFNRV} = "YES" then gosub commandSFSAIcfnrv

@return

@label commandSFSAIcfnrv

@set {command} = "SFSAI:SNB="

@set {data} = ",SERVICE=CFNRV,MISC=RTIME-" + {RtimeCFNRV}

@gosub AppendCommandToFile

@gosub commdatazero

@return

@label commandSUDNCcfnrv

@set {command} = "SUDNC:SNB="

@set {data} = ",SERVICE=CFNRV,DIN="+{DinCFBV}

@gosub AppendCommandToFile

@gosub commdatazero

@return

@@-------------------------------------------------------@@

@@ CALL FORWARDING UNCONDITIONAL VARIABLE NUMBER SERVICE @@

@@-------------------------------------------------------@@

@label CFUVdata

@if {lineCFUVresult} = "no service" then return

@gosub commdatazero

@set {CfuvActivLine} = {lineCFUV} + 12

@set {CfuvDinLine} = {lineCFUV} + 12

@copy {_lines[{CfuvActivLine}]} {ActivCFUV} 1 3

@copy {_lines[{CfuvDinLine}]} {DinCFUV} 20 20

@if {DinCFUV} <> "" then gosub commandSUDNCcfuv

@if {ActivCFUV} = "YES" then gosub commandSFSAIcfuv

@return

@label commandSUDNCcfuv

@set {command} = "SUDNC:SNB="

@set {data} = ",SERVICE=CFUV,DIN="+{DinCFUV}

@gosub AppendCommandToFile

@gosub commdatazero

@return

@label commandSFSAIcfuv

@set {command} = "SFSAI:SNB="

@set {data} = ",SERVICE=CFUV"

@gosub AppendCommandToFile

@gosub commdatazero

@return

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@@ @@@

@@@ Without Data Analysing @@@

@@@ @@@

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@-----------------------------@@

@@ LAST NUMBER REPETITION DATA @@

@@-----------------------------@@

@label LNRdata

@return

@@---------------------@@

@@ THREE-PARTY SERVICE @@

@@---------------------@@

@label ENQdata

@return

@@-------------------------------------------------------@@

@@ CALLING LINE IDENTIFICATION PRESENTATION SERVICE DATA @@

@@-------------------------------------------------------@@

@label CLIPdata

@return

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

@@ @@ @@@@ @@ @@@@@

@@ @@@@@@@@ @@@ @@ @@@ @@@

@@ @@@@@@@@ @@ @@ @@@@ @@

@@ @@@ @ @ @@ @@@@ @@

@@ @@@@@@@@ @@ @@ @@@@ @@

@@ @@@@@@@@ @@@ @@ @@@ @@@

@@ @@ @@@@ @@ @@@@@

@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@@

--------------

Главная страница --- Home page